package  
{
	import flash.display.Sprite;
	import flash.events.MouseEvent;
	import flash.text.TextField;
	import flash.text.TextFieldAutoSize;
	import net.user1.reactor.IClient;
	import net.user1.reactor.Reactor;
	import net.user1.reactor.ReactorEvent;
	import net.user1.reactor.Room;
	import net.user1.reactor.RoomEvent;
 
	/**
	 * ...
	 * @author naoto koshikawa
	 */
	public class TryUnion1 extends Sprite
	{
		//----------------------------------------------------------------------
		//  properties
		//----------------------------------------------------------------------
		//------------------------------
		//  private properties
		//------------------------------
		/**
		 * 
		 */
		private var _reactor:Reactor;
 
		/**
		 * 
		 */
		private var _room:Room;
 
		//----------------------------------------------------------------------
		//  methods
		//----------------------------------------------------------------------
		//------------------------------
		//  public methods
		//------------------------------
		/**
		 * 
		 */
		public function TryUnion1() 
		{
			connect();
		}
 
		//------------------------------
		//  private methods
		//------------------------------
		/**
		 * 
		 */
		private function connect():void
		{
			// Union Client SDKのReactorクラスをインスタンス化します
			_reactor = new Reactor();
 
			_reactor.addEventListener(
				ReactorEvent.READY, _reactor_readyHandler);
			// Unioｎ　Serverへ接続します。
			_reactor.connect("tryunion.com", 9100);
		}
 
		/**
		 * サーバのRoomヘ入室します
		 */
		private function join():void
		{
			// la.fla.tryunion1というRoomを作成します。
			// すでに他のクライアントが同名の部屋を作成していた場合
			// はその部屋のインスタンスを取得し
			//　まだ存在していない場合は作成します。
			_room = _reactor.getRoomManager().createRoom("la.fla.tryunion1");
 
			// Room入室時のイベントを待機します
			_room.addEventListener(RoomEvent.JOIN, _room_joinHandler);
 
			// shared という名前でメッセージを送信した場合のイベントを待機します
			_room.addMessageListener("shared", _room_sharedHandler);
 
			// Roomへ入室します
			_room.join();
		}
 
		/**
		 * マウスのハンドラを設定します
		 */
		private function activate():void
		{
			stage.addEventListener(
				MouseEvent.CLICK, stage_mouseClickHandler
			);
		}
 
		//----------------------------------------------------------------------
		//  event handler
		//----------------------------------------------------------------------
		/**
		 * Reactorインスタンスのconnectメソッド実行後、
		 * UnionServerへ接続した際に実行されるハンドラ
		 * @param	event
		 */
		private function _reactor_readyHandler(event:ReactorEvent):void
		{
			join();
		}
 
		/**
		 * Roomインスタンスのjoinメソッド実行後、
		 * UnionServerのRoomへ接続した際に実行されるハンドラ
		 * @param	event
		 */
		private function _room_joinHandler(event:RoomEvent):void
		{
			activate();
		}
 
		/**
		 * sharedという名前で送信したメッセージをUnion Server経由で受け取った際
		 * に実行されるハンドラ
		 * @param	fromClient	メッセージを送信したクライアントオブジェクト
		 * @param	color	メッセージ送信時に第一引数に指定した値
		 * @param	sharedX	メッセージ送信時に第二引数に指定した値
		 * @param	sharedY	メッセージ送信時に第三引数に指定した値
		 */
		private function _room_sharedHandler(
				fromClient:IClient, color:uint,
				sharedX:Number, sharedY:Number):void
		{
			graphics.beginFill(color);
			graphics.drawCircle(sharedX, sharedY, 10);
 
			var textField:TextField = new TextField();
			textField.autoSize = TextFieldAutoSize.LEFT;
			textField.text = fromClient.getClientID();
			textField.x = sharedX;
			textField.y = sharedY;
			textField.mouseEnabled = false;
			addChild(textField);
		}
 
		/**
		 * stage上でクリックした際に実行されるハンドラ
		 * @param	event
		 */
		private function stage_mouseClickHandler(event:MouseEvent):void
		{
			// Roomに色とマウスのｘ座標、ｙ座標を引数とした shared　という名の
			//　メッセージを送信します
			_room.sendMessage(
				"shared", true, null, 
				0x777777 + 0x888888 * Math.random(),
				event.stageX, event.stageY
			);
		}
	}
}